Quicksilver to Mori

Another way to add text in Quicksilver is to invoke Quicksilver then hit "." (period) to put it into text mode. You can then enter any text you want, or paste the clipboard. Once you're done, tab to the Actions pane, type the first letter or two of your Applescript and hit enter. (This is the method Merlin Mann documents on 43folders.com).

it's the same number of keystrokes as Jesse's example, but I find it faster since Quicksilver only has to search the Actions folder instead of the entire drive for your Applescript.

I haven't figured out how to enumerate Mori folders in Quicksilver, but you can easily create several scripts, each of which stick the text into a different Mor folder.

--
Leo Laporte
Chief TWiT

Yeah, that works a treat. Ta.

This is amazingly useful. I've created a modified version that places the typed text into the body of the note and uses the first 60 characters for the title:

using terms from application "Quicksilver"
on process text theText
tell application "Mori"
tell front document
set inFolder to entry named "Inbox"
set theTitle to ((characters 1 thru 60 of theText) as string)
make new entry at end of entries of inFolder with properties {name:theTitle, note:theText}
end tell
end tell
end process text
end using terms from

What I'd like is to have the ability to define the title by using some code at the end of the title text. For instance, to write:

This is the title||This is the body of the note.

Or something of the sort.

Here's my version of the script. This one breaks title vs contents based on the first newline in the text - you can insert a newline in Quicksilver's text entry by hitting option-return. It also adopts the Inbox check of the previous posted revised script.


using terms from application "Quicksilver"
    on process text theText
        set delims to AppleScript's text item delimiters
        set AppleScript's text item delimiters to ASCII character 10
        set theLines to every text item of theText
        set AppleScript's text item delimiters to delims
        set theTitle to first item of theLines
        set theBody to ""
        repeat with i from 2 to count of theLines
            set theBody to theBody & item i of theLines & return
        end repeat
        tell application "Mori"
            tell front document
                if exists entry named "Inbox" then
                    set inFolder to entry named "Inbox"
                else
                    set inFolder to (make new entry with properties {name:"Inbox", kind:"public.folder"})
                end if
                make new entry at end of entries of inFolder with properties {name:theTitle, note:theBody}
            end tell
        end tell
    end process text
end using terms from


--
And remember, no matter where you go, there you are.
-Buckaroo Banzai

This isn't working for me unfortunately; here's what I do:
- I bring up quicksilver
- Search for in.scpt (which is in the actions folder in quicksilver app support) which contains this applescript:

using terms from application "Quicksilver"
on process text theText
tell application "Mori"
tell front document
set inFolder to entry named "Inbox"
make new entry at end of entries of inFolder with properties {name:theText}
end tell
end tell
end process text
end using terms from

- Then I press tab twice as suggested and a third box doesn't appear, it just switches between the two boxes (there's no 'process text' box at all.)

I then tried Leo's method, but that didn't work either, I entered text in the first box, then tabbed to the next, selected in.scpt, and pressed enter, nothing happens in mori....

Any help would be much appreciated, thanks.

You can also use the "Service Menu Module" plugin to completely avoid AppleScript (picture).

The quietude in here makes me worry that I'm missing out on an existing solution. That aside, here's my latest revision with options for tags and a due date. I also renamed the script "send to mori.scpt" because "in.scpt" was obscure without any advantage.

--Quicksilver to Mori entry Applescript
--Format:
--    [title];;[body[;;[tag[,tag[,...]][;;[date]]]]]
--  Examples:
--        Bookstore;;Buy a book on Applescript
--        Bookstore;;Buy a book on Applescript;;todo,programming
--        Bookstore;;Buy a book on Applescript;;todo,programming;;7/15/09
--        Bookstore;;Buy a book on Applescript;;;;7/15/09

using terms from application "Quicksilver"
    on process text theText
        set counter to 1
        set delims to AppleScript's text item delimiters
        set AppleScript's text item delimiters to {";;"}
        set theLines to every text item of theText
        set titleRoot to first item of theLines
        set theTitle to titleRoot
        set theBody to second item of theLines
        try
            set theTags to third item of theLines
        on error
            set theTags to ""
        end try
        try
            set theDueDate to fourth item of theLines
            set theDueDateAsDate to date theDueDate
        on error what
            set theDueDate to ""
        end try
        set AppleScript's text item delimiters to delims
        tell application "Mori"
            tell front document
                repeat while exists entry named theTitle
                    set theTitle to titleRoot & " " & (counter)
                    set counter to counter + 1
                end repeat
                set inFolder to entry named "Inbox"
                if theDueDate is equal to "" then
                    set theProperties to {name:theTitle, note:theBody}
                else
                    set theProperties to {name:theTitle, note:theBody, due date:theDueDateAsDate}
                end if
                make new entry at end of entries of inFolder with properties theProperties
                if theTags is not equal to "" then
                    set AppleScript's text item delimiters to {","}
                    set theTagsList to every text item of theTags
                    repeat with aTag in theTagsList
                        add entry named theTitle tag aTag
                    end repeat
                end if
            end tell
        end tell
    end process text
end using terms from